SetLocale 関数

SetLocale(lcid)

グローバルなロケール設定を行い、直前のロケール設定値を返します。

引数

lcid
ロケール情報を識別するための 32 ビットの値、または一意の言語コードを指定します。指定可能な値については、ロケール ID の一覧を参照してください。

解説

lcid がゼロ ("0") の場合は、現在のシステムのロケール設定が適用されます。

ロケールには、言語、国/地域、および文化的な慣習に関連するユーザーごとの各種設定が含まれています。キーボード レイアウト、文字の並び順、および日付、時間、数値、通貨の書式は、このロケールによって決定されます。

使用例

次次のコードは SetLocale 関数の使用例です。このコードを使用するには、コード例全体をコピーしてから、標準的な HTML ファイルの <BODY> タグと </BODY> タグの間にコードを貼り付けてください。

英語 (U.K.) の書式で日付を入力してください:
 <input type="text" id="UKDate" size="20"><br>
対応する英語 (U.S.) の日付:
 <input type="text" id="USdate" size="20"><br>
 <input type="button" value="Convert" id="button1"><br>
ドイツ語の書式で、通貨の値を入力してください:
   <input type="text" id="GermanNumber" size="20"><br>
対応する英語 (U.K.) の通貨:
 <input type="text" id="USNumber" size="20"><br>
 <input type="button" value="Convert" id="button2"><br>

<script language="vbscript">
Dim currentLocale
' 現在のロケールを取得します。
currentLocale = GetLocale

Sub Button1_onclick
  Dim original
  original = SetLocale("en-gb")
  mydate = CDate(UKDate.value)
  ' IE では通常、ロケールは英語 (U.S.) に設定されているので、
  ' 変数 currentLocale を使用してロケールを英語 (U.S.) に設定します。
  original = SetLocale(currentLocale)
  USDate.value = FormatDateTime(mydate,vbShortDate)
End Sub

Sub button2_onclick
  Dim original
  original = SetLocale("de")
  myvalue = CCur(GermanNumber.value)
  original = SetLocale("en-gb")
  USNumber.value = FormatCurrency(myvalue)
End Sub

</script> 
              

関連

GetLocale 関数 | ロケール ID (LCID) の一覧

このページの先頭へ